Bluetooth QML Chat Example

Bluetooth QML Chat example shows how to use the Qt Bluetooth QML API to communicate with another application on a remote device using Bluetooth.

The Bluetooth QML Chat example implements a simple chat program between two parties. The application acts as client and attempts to connect to a Bluetooth socket server. It uses the BluetoothDiscoveryModel type to find the server and BluetoothSocket type to facilitate the data exchange.

运行范例

要运行范例从 Qt Creator ，打开欢迎模式，然后选择范例从范例。更多信息，拜访构建和运行范例 .

The example only works in connection with the 蓝牙聊天范例 . The Bluetooth Chat example launches the chat service and advertises it via the Bluetooth SDP protocol. It is important that the device running the Bluetooth Chat example actively advertises its SDP services. This can be checked using the QBluetoothLocalDevice::hostMode 特性。

Interacting with the Server

The example application immediately starts the service discovery using the BluetoothDiscoveryModel 类型：

BluetoothDiscoveryModel {
    id: btModel
    running: true
    discoveryMode: BluetoothDiscoveryModel.FullServiceDiscovery
    uuidFilter: targetUuid //e8e10f95-1a70-4b27-9ccf-02010264e9c8
}

uuidFilter property is used to only search for the chat server UUID and the running property activates the search. Once a service with a matching UUID is found the model emits the serviceDiscovered(BluetoothService) 信号。

    onServiceDiscovered: {
        if (serviceFound)
            return
        serviceFound = true
        console.log("Found new service " + service.deviceAddress + " " + service.deviceName + " " + service.serviceName);
        searchBox.appendText("\nConnecting to server...")
        remoteDeviceName = service.deviceName
        socket.setService(service)
    }

BluetoothService type encapsulates the details of the found chat server, such as the name and description of the service, as well as the name and address of the Bluetooth device offering the chat server. It is passed to the BluetoothSocket to establish the connection.

Once the connection is established the socket's state is managed as follows:

BluetoothSocket {
    id: socket
    connected: true
    onSocketStateChanged: {
        switch (socketState) {
            case BluetoothSocket.Unconnected:
            case BluetoothSocket.NoServiceSet:
                searchBox.animationRunning = false;
                searchBox.setText("\nNo connection. \n\nPlease restart app.");
                top.state = "begin";
                break;
            case BluetoothSocket.Connected:
                console.log("Connected to server ");
                top.state = "chatActive"; // move to chat UI
                break;
            case BluetoothSocket.Connecting:
            case BluetoothSocket.ServiceLookup:
            case BluetoothSocket.Closing:
            case BluetoothSocket.Listening:
            case BluetoothSocket.Bound:
                break;
        }
    }
    //...
}

The payload is received via the stringData 特性：

    onStringDataChanged: {
        console.log("Received data: " )
        var data = remoteDeviceName + ": " + socket.stringData;
        data = data.substring(0, data.indexOf('\n'))
        chatContent.append({content: data})
    }

And sent by setting the same property:

socket.stringData = data

文件：

图像：